home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_emacs.idb / usr / freeware / share / emacs / 19.34 / lisp / saveplace.el.z / saveplace.el
Encoding:
Text File  |  1998-10-28  |  8.6 KB  |  230 lines
  1. ;;; saveplace.el --- automatically save place in files.
  2.  
  3. ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Karl Fogel <kfogel@cs.oberlin.edu>
  6. ;; Maintainer: FSF
  7. ;; Created: July, 1993
  8. ;; Keywords: bookmarks, placeholders
  9.  
  10. ;; This file is part of GNU Emacs.
  11.  
  12. ;; GNU Emacs is free software; you can redistribute it and/or modify
  13. ;; it under the terms of the GNU General Public License as published by
  14. ;; the Free Software Foundation; either version 2, or (at your option)
  15. ;; any later version.
  16.  
  17. ;; GNU Emacs is distributed in the hope that it will be useful,
  18. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20. ;; GNU General Public License for more details.
  21.  
  22. ;; You should have received a copy of the GNU General Public License
  23. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25. ;; Boston, MA 02111-1307, USA.
  26.  
  27. ;;; Commentary:
  28.  
  29. ;; Automatically save place in files, so that visiting them later
  30. ;; (even during a different Emacs session) automatically moves point
  31. ;; to the saved position, when the file is first found.  Uses the
  32. ;; value of buffer-local variable save-place to determine whether to
  33. ;; save position or not.
  34. ;;
  35. ;; Thanks to Stefan Schoef, who sent a patch with the
  36. ;; `save-place-version-control' stuff in it.
  37.  
  38. ;;; Code:
  39.  
  40. ;; this is what I was using during testing:
  41. ;; (define-key ctl-x-map "p" 'toggle-save-place)
  42.  
  43. (defvar save-place-alist nil
  44.   "Alist of saved places to go back to when revisiting files.
  45. Each element looks like (FILENAME . POSITION);
  46. visiting file FILENAME goes automatically to position POSITION
  47. rather than the beginning of the buffer.
  48. This alist is saved between Emacs sessions.")
  49.  
  50. (defvar save-place nil
  51.   "*Non-nil means automatically save place in each file.
  52. This means when you visit a file, point goes to the last place
  53. where it was when you previously visited the same file.
  54. This variable is automatically buffer-local.
  55.  
  56. If you wish your place in any file to always be automatically saved,
  57. simply put this in your `~/.emacs' file:
  58.  
  59. \(setq-default save-place t\)")
  60.  
  61. (make-variable-buffer-local 'save-place)
  62.  
  63. (defvar save-place-file (convert-standard-filename "~/.emacs-places")
  64.   "*Name of the file that records `save-place-alist' value.")
  65.  
  66. (defvar save-place-version-control 'nospecial
  67.   "*Controls whether to make numbered backups of master save-place file.
  68. It can have four values: t, nil, `never', and `nospecial'.  The first
  69. three have the same meaning that they do for the variable
  70. `version-control', and the final value `nospecial' means just use the
  71. value of `version-control'.")
  72.  
  73. (defvar save-place-loaded nil
  74.   "Non-nil means that the `save-place-file' has been loaded.")
  75.  
  76. (defvar save-place-limit nil
  77.   "Maximum number of entries to retain in the list; nil means no limit.")
  78.  
  79. (defun toggle-save-place (&optional parg)
  80.   "Toggle whether to save your place in this file between sessions.
  81. If this mode is enabled, point is recorded when you kill the buffer
  82. or exit Emacs.  Visiting this file again will go to that position,
  83. even in a later Emacs session.
  84.  
  85. If called with a prefix arg, the mode is enabled if and only if
  86. the argument is positive.
  87.  
  88. To save places automatically in all files, put this in your `.emacs' file:
  89.  
  90. \(setq-default save-place t\)"
  91.   (interactive "P")
  92.   (if (not buffer-file-name)
  93.       (message "Buffer `%s' not visiting a file" (buffer-name))
  94.     (if (and save-place (or (not parg) (<= parg 0)))
  95.     (progn
  96.       (message "No place will be saved in this file")
  97.       (setq save-place nil))
  98.       (message "Place will be saved")
  99.       (setq save-place t))))
  100.  
  101. (defun save-place-to-alist ()
  102.   ;; put filename and point in a cons box and then cons that onto the
  103.   ;; front of the save-place-alist, if save-place is non-nil.
  104.   ;; Otherwise, just delete that file from the alist.
  105.   ;; first check to make sure alist has been loaded in from the master
  106.   ;; file.  If not, do so, then feel free to modify the alist.  It
  107.   ;; will be saved again when Emacs is killed.
  108.   (or save-place-loaded (load-save-place-alist-from-file))
  109.   (if buffer-file-name
  110.       (progn
  111.         (let ((cell (assoc buffer-file-name save-place-alist)))
  112.           (if cell
  113.               (setq save-place-alist (delq cell save-place-alist))))
  114.         (if save-place
  115.             (setq save-place-alist
  116.           (cons (cons buffer-file-name
  117.                   (if (not (eq major-mode 'hexl-mode))
  118.                   (point)
  119.                 (1+ (hexl-current-address))))
  120.                         save-place-alist))))))
  121.  
  122. (defun save-place-alist-to-file ()
  123.   (let ((file (expand-file-name save-place-file)))
  124.     (save-excursion
  125.       (message "Saving places to %s..." file)
  126.       (set-buffer (get-buffer-create " *Saved Places*"))
  127.       (delete-region (point-min) (point-max))
  128.       (if (file-readable-p file)
  129.           (insert-file-contents file))
  130.       (delete-region (point-min) (point-max))
  131.       (goto-char (point-min))
  132.       (print save-place-alist (current-buffer))
  133.       (let ((version-control
  134.              (cond
  135.               ((null save-place-version-control) nil)
  136.               ((eq 'never save-place-version-control) 'never)
  137.               ((eq 'nospecial save-place-version-control) version-control)
  138.               (t
  139.                t))))
  140.         (write-file file)
  141.         (kill-buffer (current-buffer))
  142.         (message "Saving places to %s...done" file)))))
  143.  
  144. (defun load-save-place-alist-from-file ()
  145.   (if (not save-place-loaded)
  146.       (progn
  147.         (setq save-place-loaded t)
  148.         (let ((file (expand-file-name save-place-file)))
  149.           ;; make sure that the alist does not get overwritten, and then
  150.           ;; load it if it exists:
  151.           (if (file-readable-p file)
  152.               (save-excursion
  153.                 (message "Loading places from %s..." save-place-file)
  154.                 ;; don't want to use find-file because we have been
  155.                 ;; adding hooks to it.
  156.                 (set-buffer (get-buffer-create " *Saved Places*"))
  157.                 (delete-region (point-min) (point-max))
  158.                 (insert-file-contents file)
  159.                 (goto-char (point-min))
  160.                 (setq save-place-alist 
  161.                       (car (read-from-string
  162.                             (buffer-substring (point-min) (point-max)))))
  163.  
  164.                 ;; If there is a limit, and we're over it, then we'll
  165.                 ;; have to truncate the end of the list:
  166.                 (if save-place-limit
  167.                     (if (<= save-place-limit 0)
  168.                         ;; Zero gets special cased.  I'm not thrilled
  169.                         ;; with this, but the loop for >= 1 is tight.
  170.                         (setq save-place-alist nil)
  171.                       ;; Else the limit is >= 1, so enforce it by
  172.                       ;; counting and then `setcdr'ing.
  173.                       (let ((s save-place-alist)
  174.                             (count 1))
  175.                         (while s
  176.                           (if (>= count save-place-limit)
  177.                               (setcdr s nil)
  178.                             (setq count (1+ count)))
  179.                           (setq s (cdr s))))))
  180.                   
  181.                 (kill-buffer (current-buffer))
  182.                 (message "Loading places from %s...done" file)
  183.                 t)
  184.             t)
  185.           nil))))
  186.  
  187. (defun save-places-to-alist ()
  188.   ;; go through buffer-list, saving places to alist if save-place is
  189.   ;; non-nil, deleting them from alist if it is nil.
  190.   (let ((buf-list (buffer-list)))
  191.     (while buf-list
  192.       ;; put this into a save-excursion in case someone is counting on
  193.       ;; another function in kill-emacs-hook to act on the last buffer
  194.       ;; they were in:
  195.       (save-excursion
  196.     (set-buffer (car buf-list))
  197.     ;; save-place checks buffer-file-name too, but we can avoid
  198.     ;; overhead of function call by checking here too.
  199.     (and buffer-file-name (save-place-to-alist))
  200.     (setq buf-list (cdr buf-list))))))
  201.  
  202. (defun save-place-find-file-hook ()
  203.   (or save-place-loaded (load-save-place-alist-from-file))
  204.   (let ((cell (assoc buffer-file-name save-place-alist)))
  205.     (if cell
  206.     (progn
  207.       (or after-find-file-from-revert-buffer
  208.           (goto-char (cdr cell)))
  209.           ;; and make sure it will be saved again for later
  210.           (setq save-place t)))))
  211.  
  212. (defun save-place-kill-emacs-hook ()
  213.   ;; First update the alist.  This loads the old save-place-file if nec.
  214.   (save-places-to-alist)
  215.   ;; Now save the alist in the file, if we have ever loaded the file
  216.   ;; (including just now).
  217.   (if save-place-loaded
  218.       (save-place-alist-to-file)))
  219.  
  220. (add-hook 'find-file-hooks 'save-place-find-file-hook t)
  221.  
  222. (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook)
  223.  
  224. (add-hook 'kill-buffer-hook 'save-place-to-alist)
  225.  
  226. (provide 'saveplace) ; why not...
  227.  
  228. ;;; saveplace.el ends here
  229.  
  230.